Re: Dragon32 Gamebase Beta1 Here
Posted: Sun Oct 20, 2019 4:13 pm
Perfect thanks.mad. wrote: ↑Sat Oct 26, 2019 1:19 pmLarkspur part 1 - Waldorf Is Trapped (HB & JS)[fixed].cas
That game is there but it needs relinking with the one in update (rc5)
Hobson Bullman and John Smallwood/Larkspur part 1 - Waldorf Is Trapped.zip
Larkspur part 1 - Waldorf Is Trapped (HB & JS)[fixed2].cas
forgot to add King of Valley due to xroar crashing when it's run.
The new emulator code used incorrect path "/" instead of "\" in the Windows build.
Can't find any snapshot v0.37 on that link .mad., has it been removed?.mad. wrote: ↑Fri Jun 12, 2020 9:55 amThe new emulator code used incorrect path "/" instead of "\" in the Windows build.
This caused the command to terminate on the file attached.
It was fixed by sixxie in yesterday afternoons snapshot v0.37.
The script does need a small tweak for the updated type commands...
\n [new line] should be changed to \r [return]
and quotes should now be inside quotes (3 quotes to type 1 quote)
example
Add_CLP( -type RUN"""DISCUP.BIN"""\r)
Add_CLP( -type BOOT\r)
new working build here...
http://www.6809.org.uk/tmp/xroar/
No, it's just my confusion with the numbers.
Code: Select all
;******************************
;* XROAR v0.37 *
;* 11th June 2020 *
;* Dragon 32/64, Tano, CoCo *
;* Script by .mad. *
;* Xroar Manual sendkeys v1.3 *
;******************************
; xroar 0.36 path uses incorrect slash "/" for gamebase to attach files in Windows.
; fixed in 0.36.110
; All -type filenames in GEMUS need to be in UPPERCASE!!!
; PLEASE SET YOUR EMULATOR PROPERTIES AS FOLLOWS:
;
; Emulator File: XRoar.exe
; Use Short Filenames: no
; File Types: cas;pak;dtx;dgn;s19;vdk;sna
; (Compressed File Types: ZIP)
; If a Game needs a specific machine use the following keytypes:
; machine=dragon32 - Dragon 32 (PAL) (Default)
; machine=dragon64 - Dragon 64 (PAL)
; machine=tano - Tano Dragon (NTSC)
; machine=coco - Tandy Colour Computer (PAL
; machine=cocous - Tandy Color Computer (NTSC)
; machine=coco2b - coco2b pal
; machine=coco2bus - coco2b ntsc
; Startup keytypes:
; Startup=cload - Basic Application (may require RUN)
; Startup=cloadm - Machine Code Application (Autostarting)
; Startup=cloadm:exec - Machine Code Application -requires EXEC to run.
; pclear=# (1-8) - PCLEAR8 to clear memory before typing CLOADM
; diskboot=menu.bas
; casboot=menu.bas
;Some games require commands to be entered before they can load correctly
;for example to enable the dragon64 to use the 64K Ram you need to enter 64k mode by typing EXEC (The cursor will flash blue to indicate 64K mode)
;to enter the command type startup=d6432k in the GEMUS window.
;####################
; possible keymap codes (uk||de||fr||us||fr_CA)
Add_CLP( -keymap uk)
;####################
;Setup game to use cursor keys for left Joystick by default(Joyport2) or right joystick(Joyport1)
;--------------------------------
; -joy-virtual name
; none, joy0, joy1, kjoy0, mjoy0
;--------------------------------
;Right Joystick
If Control = JoyPort1
if key_autocenter CONTAINS(analog)
;use mouse for better control
Add_CLP( -joy-right mjoy0)
Else
Add_CLP( -joy-right joy0)
End If
if key_joystick2 CONTAINS(yes)
Add_CLP( -joy-left joy1)
Else
Add_CLP( -joy-left none)
End If
;Left Joystick
ElseIf Control = JoyPort2
if key_autocenter CONTAINS(analog)
;use mouse for better control
Add_CLP( -joy-left mjoy0)
Else
Add_CLP( -joy-left joy0)
End If
if key_joystick2 CONTAINS(yes)
Add_CLP( -joy-right joy1)
else
Add_CLP( -joy-right none)
End If
;default controls keyboard only
else
Add_CLP( -joy-left none -joy-right none)
End If
If Key_machine CONTAINS(DRAGON64)
Add_CLP( -machine dragon64)
If key_cart CONTAINS(delta)
Add_CLP( -cart delta)
ElseIf key_dos CONTAINS(no)
Add_CLP( -nodos)
Else
Add_CLP( -cart dragondos)
End If
;Use this for NTSC games (black and white)
ElseIf Key_machine CONTAINS(Tano)
Add_CLP( -machine tano -ccr simple)
Add_CLP( -cart dragondos)
ElseIf Key_machine CONTAINS(coco)
Add_CLP( -machine coco)
ElseIf Key_machine CONTAINS(cocous)
Add_CLP( -machine cocous)
ElseIf Key_machine CONTAINS(coco2b)
Add_CLP( -machine coco2b)
If key_dos CONTAINS(yes)
Add_CLP( -cart rsdos)
Else If gametype CONTAINS(dsk)
Add_CLP( -cart rsdos)
Else
Add_CLP( -nodos)
End If
ElseIf Key_machine CONTAINS(coco2||coco2bus)
Add_CLP( -machine coco2bus)
If key_dos CONTAINS(yes)
Add_CLP( -cart rsdos)
Else If gametype CONTAINS(dsk)
Add_CLP( -cart rsdos)
Else
Add_CLP( -nodos)
End If
Else
;choose a normal Dragon32 as default
Add_CLP( -machine dragon32)
If key_cart CONTAINS(delta)
Add_CLP( -cart delta)
ElseIf key_dos CONTAINS(yes)
Add_CLP( -cart dragondos)
Else If gametype CONTAINS(vdk)
Add_CLP( -cart dragondos)
else
Add_CLP( -nodos)
End If
End If
;-nobas
;-noextbas
;-noaltbas
If PalNTSC = NTSC
; artifacting (orange)
Add_CLP( -tv-type ntsc)
ElseIf PalNTSC = BOTH
; artifacting (blue)
Add_CLP( -tv-type ntsc)
Else
;black and white
Add_CLP( -tv-type pal)
End if
;Load tape or disk manually with stored GEMUS commands.
; ONLY needed if Xroar auto boot fails.
; uses GEMUS "startup" instead of "boot" in MAME script.
If key_poke CONTAINS(*)
ADD_CLP( -load "%gamepathfile%")
Add_CLP( -type POKE%poke_value%\r)
Add_CLP( -type \r%boot_value%\r)
If key_boot CONTAINS(CLOAD)
Add_CLP( -type RUN\r)
End If
Run_Emulator()
Elseif key_exec CONTAINS(*)
; Memory location to jump into after loading.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM:EXEC%exec_value%\r)
Run_Emulator()
Elseif key_code CONTAINS(*)
; FILE=FILENAME when CODE is used.
; Memory location to load file at.
Add_CLP( -load "%gamepathfile%")
if key_file CONTAINS(*)
Add_CLP( -type CLOADM"""%file_value%""",&H%code_value%:EXEC\r)
else
Add_CLP( -type CLOADM"""""",&H%code_value%:EXEC\r)
End If
Run_Emulator()
ElseIf Key_clear CONTAINS(*)
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLEAR%clear_value%\r)
Add_CLP( -type \r%boot_value%\r)
Run_Emulator()
Elseif key_clearh CONTAINS(*)
; CLEAR200,&H6000
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLEAR%clearh_value%,&H%h_value%\r)
Add_CLP( -type CLOADM:EXEC\r)
Run_Emulator()
ElseIf Key_pclear CONTAINS(*)
; PCLEAR# (1-8) clear memory for the code.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type PCLEAR%pclear_value%\r)
Add_CLP( -type \r%boot_value%\r)
If key_boot CONTAINS(CLOAD)
Add_CLP( -type \rRUN\r)
End If
Run_Emulator()
ElseIf Key_casboot CONTAINS(*)
; select file on compilation tape to load.
Add_CLP( -load "%gamepathfile%")
if key_casfile CONTAINS(BAS)
Add_CLP( -type CLOAD"%casboot_value%\r)
Else
Add_CLP( -type CLOADM"""%casboot_value%"""\r)
End If
Run_Emulator()
ElseIf Key_startup CONTAINS(d64bas)
;Dragon 64 in 64k mode
;from DOS type... EXEC (blue cursor = 64k mode)
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type EXEC\r)
Run_Emulator_Send_Keys([3]CLOAD{enter}||50)
ElseIf Key_boot CONTAINS(CLOAD)
;load a BASIC program from tape. may also require RUN to be typed.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOAD\r)
;Enter line number to RUN in BASIC.
If key_run CONTAINS(*)
Add_CLP( -type RUN%run_value%\r)
else
Add_CLP( -type RUN\r)
End If
Run_Emulator()
ElseIf Key_boot CONTAINS(CLOADM)
;Load a machine code program from tape.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM\r)
Run_Emulator()
ElseIf Key_boot CONTAINS(CLOADM:EXEC)
;load machine code from tape. also requires EXEC to be typed from DOS prompt to run the code.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM:EXEC\r)
Run_Emulator()
ElseIf Key_boot CONTAINS(CLOADM:CLOAD)
;load 2 files. machine code, then BASIC. *when tape motor is stuck ON in emulator.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM:CLOAD\r)
Add_CLP( -type \rRUN\r)
Run_Emulator()
ElseIf Key_boot CONTAINS(CLOADM:RUN)
;load machine code from tape. also requires RUN to be typed from DOS prompt to run the code.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM:RUN\r)
Run_Emulator()
ElseIf Key_boot CONTAINS(CLOADM:CLOADM)
;load machine code from tape. also requires CLOADM to be typed from DOS prompt to run the code.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type CLOADM:CLOADM\r)
Run_Emulator()
;-----------------
;Disks
;-----------------
ElseIf key_mode CONTAINS(discup)
;move DragonDOS to higher memory.
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type RUN"""DISCUP.BIN"""\r)
Add_CLP( -type BOOT\r)
Run_Emulator()
ElseIf Key_mode CONTAINS(infocom)
;link (non booting) adventure disk as the "game file" in drive 1, engine.vdk in drive 2.
Add_CLP( -load "%gamepathfile%" -load "%gamepath%\ENGINE.VDK")
Add_CLP( -type LOAD"""2:ENG04V32.BIN""":EXEC&H1100\r)
Run_Emulator()
ElseIf key_diskboot CONTAINS(*)
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type RUN"""%diskboot_value%"""\r)
Run_Emulator()
;Requires 2 disks inserted to load (Disk A = drive#1, Disk B = drive#2).
; files must be in GameBase name format "gamename_disk 1.vdk", "gamename_disk 2.vdk".
ElseIf Key_2disk CONTAINS(yes)
Add_CLP( -load "%gamepathfile%" -load "%gamepathfile(1)%")
Add_CLP( -type BOOT\r)
Run_Emulator()
ElseIf Key_dir CONTAINS(yes)
Add_CLP( -load "%gamepathfile%")
Add_CLP( -type DIR\r)
Run_Emulator()
;---------------------
ElseIf Key_machine CONTAINS (coco2||coco2b)
; CoCo 2 Compilation disks
If gametype CONTAINS(DSK)
Add_CLP( -load "%gamepathfile%")
If key_boot CONTAINS (*.BAS)
Add_CLP( -type RUN"""%boot_value%"""\r)
;bin
else if key_autorun CONTAINS (no||off)
Add_CLP( -type LOADM"""%boot_value%"""\r)
Else
Add_CLP( -type LOADM"""%boot_value%""":EXEC\r)
End If
End If
;---------------------
; Use Xroar's built-in settings for auto running files.
; It doesn't work for everything, but it's a very good default option.
Else
Add_CLP( -run "%gamepathfile%")
Run_Emulator()
End If